Consistently use the preferences and history names in the bff code base

- rename openapi clients (client-portal-prefs -> client-preferences, client-portal-history -> client-history, client-portal-keycloak -> client-keycloak)
- rename related spring configurations (portal-prefs -> preferences, portal-history -> history)
- rename related environment variables (PORTAL_PREFS_URL -> PREFERENCES_URL, PORTAL_HISTORY_URL -> HISTORY_URL)
Note that the changes to the configurations and variables affect external services using it and the bff chart

Issue-ID: PORTALNG-49
Change-Id: I434abdf130a5a81534c2387143b296122408d452
Signed-off-by: Fiete Ostkamp <Fiete.Ostkamp@telekom.de>

1 files changed, 62 insertions, 0 deletions

diff --git a/openapi/client-keycloak/build.gradle b/openapi/client-keycloak/build.gradle
new file mode 100644
index 0000000..46c842d
--- /dev/null
+++ b/openapi/client-keycloak/build.gradle
@@ -0,0 +1,62 @@
+plugins {
+  id 'java'
+  id 'idea'
+  id 'org.springframework.boot'
+  id 'io.spring.dependency-management'
+  id 'org.openapi.generator'
+}
+
+dependencies {
+  implementation 'org.springframework.boot:spring-boot-starter-webflux'
+  implementation "org.openapitools:openapi-generator:$openapiVersion"
+}
+
+openApiGenerate {
+    generatorName = "java"
+    library = "webclient"
+    inputSpec = "${project.projectDir}/src/api.yaml"
+    outputDir = "${project.buildDir}/openapi"
+    configOptions = [
+      openApiNullable     : "false",
+      dateLibrary         : "java8",
+      serializationLibrary: "jackson",
+      useJakartaEe        : "true",
+    ]
+    typeMappings = [
+            "File": "org.springframework.core.io.buffer.DataBuffer"
+    ]
+    generateApiTests = false
+    generateApiDocumentation = false
+    generateModelTests = false
+    generateModelDocumentation = false
+    invokerPackage = "org.onap.portalng.bff.openapi.client_keycloak"
+    apiPackage = "org.onap.portalng.bff.openapi.client_keycloak.api"
+    modelPackage = "org.onap.portalng.bff.openapi.client_keycloak.model"
+    modelNameSuffix = "KeycloakDto"
+}
+
+compileJava {
+  dependsOn tasks.openApiGenerate
+}
+
+sourceSets {
+  main {
+    java {
+      srcDirs += file("$buildDir/openapi/src/main/java")
+    }
+  }
+}
+
+idea {
+  module {
+    generatedSourceDirs += file("$buildDir/openapi/src/main/java")
+  }
+}
+
+bootJar {
+    enabled = false
+}
+
+jar {
+    enabled = true
+}
\ No newline at end of file