Create Base and Sample Performance Integration Tests

- added data (folders) for different models and json data
- added base and data for cps-ncmp (registry) specific test cases
- integrated Ahila's (large) openroadm model and data
  (corrected version provided by Lee Anjella)
- created profiles to exclude/include *PerfTest
- fixed dependency test check
- included integration test for overall coverage
- increased margings in existing perf test to reduce nordix intermitten failures

Issue-ID: CPS-1516
Signed-off-by: ToineSiebelink <toine.siebelink@est.tech>
Change-Id: Ia82826f610636c14aa7e8939b385c278e5039817

1 files changed, 65 insertions, 0 deletions

diff --git a/integration-test/src/test/groovy/org/onap/cps/integration/performance/ncmp/CmHandleQueryPerfTest.groovy b/integration-test/src/test/groovy/org/onap/cps/integration/performance/ncmp/CmHandleQueryPerfTest.groovy
new file mode 100644
index 000000000..939281a73
--- /dev/null
+++ b/integration-test/src/test/groovy/org/onap/cps/integration/performance/ncmp/CmHandleQueryPerfTest.groovy
@@ -0,0 +1,65 @@
+/*
+ *  ============LICENSE_START=======================================================
+ *  Copyright (C) 2023 Nordix Foundation
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the 'License');
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an 'AS IS' BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+
+package org.onap.cps.integration.performance.ncmp
+
+import java.util.stream.Collectors
+
+import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
+import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
+
+import org.onap.cps.integration.performance.base.NcmpRegistryPerfTestBase
+
+class CmHandleQueryPerfTest extends NcmpRegistryPerfTestBase {
+
+    def objectUnderTest
+
+    def setup() { objectUnderTest = cpsQueryService }
+
+    def 'Query CM Handle IDs by a property name and value.'() {
+        when: 'a cps-path query on name-value pair is performed (without getting descendants)'
+            stopWatch.start()
+            def cpsPath = '//additional-properties[@name="neType" and @value="RadioNode"]/ancestor::cm-handles'
+            def dataNodes = cpsQueryService.queryDataNodes(NCMP_PERFORMANCE_TEST_DATASPACE, REGISTRY_ANCHOR, cpsPath, OMIT_DESCENDANTS)
+        and: 'the ids of the result are extracted and converted to xpath'
+            def xpaths = dataNodes.stream().map(dataNode -> "/dmi-registry/cm-handles[@id='${dataNode.leaves.id}']".toString() ).collect(Collectors.toSet())
+        and: 'a single get is executed to get all the parent objects and their descendants'
+            def result = cpsDataService.getDataNodesForMultipleXpaths(NCMP_PERFORMANCE_TEST_DATASPACE, REGISTRY_ANCHOR, xpaths, INCLUDE_ALL_DESCENDANTS)
+            stopWatch.stop()
+            def durationInMillis = stopWatch.getTotalTimeMillis()
+        then: 'the required operations are performed within 3 seconds'
+            recordAndAssertPerformance("CpsPath Registry attributes Query", 3_000, durationInMillis)
+        and: 'all but 1 (other node) are returned'
+            result.size() == 999
+        and: 'the tree contains all the expected descendants too'
+            assert countDataNodesInTree(result) == 5 * 999
+    }
+
+    def 'Multiple get limitation: 32,764 (~ 2^15) xpaths.'() {
+        given: 'more than 32,764 xpaths)'
+            def xpaths = []
+            (0..32_765).each { xpaths.add("/size/of/this/path/does/not/matter/for/limit[@id='" + it + "']") }
+        when: 'get single get is executed to get all the parent objects and their descendants'
+            cpsDataService.getDataNodesForMultipleXpaths(NCMP_PERFORMANCE_TEST_DATASPACE, REGISTRY_ANCHOR, xpaths, INCLUDE_ALL_DESCENDANTS)
+        then: 'no exception is thrown (limit is not present in current implementation)'
+            noExceptionThrown()
+    }
+
+}