Move cps files to root dir

Issue-ID: CIMAN-33
Signed-off-by: Jessica Wagantall <jwagantall@linuxfoundation.org>

2 files changed, 196 insertions, 0 deletions

diff --git a/cps-service/src/test/groovy/org/onap/cps/api/impl/CpServiceImplSpec.groovy b/cps-service/src/test/groovy/org/onap/cps/api/impl/CpServiceImplSpec.groovy
new file mode 100644
index 0000000000..5f42810bd5
--- /dev/null
+++ b/cps-service/src/test/groovy/org/onap/cps/api/impl/CpServiceImplSpec.groovy
@@ -0,0 +1,116 @@
+/*
+ * ============LICENSE_START=======================================================
+ *  Copyright (C) 2020 Nordix Foundation
+ *  Modifications Copyright (C) 2020 Bell Canada. All rights reserved.
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the "License");
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an "AS IS" BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+
+package org.onap.cps.api.impl
+
+import org.onap.cps.TestUtils
+import org.onap.cps.exceptions.CpsValidationException
+import org.onap.cps.spi.DataPersistencyService
+import org.opendaylight.yangtools.yang.common.Revision
+import org.opendaylight.yangtools.yang.model.api.SchemaContext
+import spock.lang.Specification
+
+class CpServiceImplSpec extends Specification {
+
+    def mockDataPersistencyService = Mock(DataPersistencyService)
+    def objectUnderTest = new CpServiceImpl()
+
+    def setup() {
+        objectUnderTest.dataPersistencyService = mockDataPersistencyService
+    }
+
+    def 'Cps Service provides to its client the id assigned by the system when storing a data structure'() {
+        given: 'that data persistency service is giving id 123 to a data structure it is asked to store'
+            mockDataPersistencyService.storeJsonStructure(_) >> 123
+        expect: 'Cps service returns the same id when storing data structure'
+            objectUnderTest.storeJsonStructure('') == 123
+    }
+
+    def 'Parse and Validate a Yang Model with a Valid Yang Model'() {
+        given: 'a yang model (file)'
+            def yangModel = TestUtils.getResourceFileContent('bookstore.yang')
+        when: 'a valid model is parsed and validated'
+            def result = objectUnderTest.parseAndValidateModel(yangModel)
+        then: 'Verify a schema context for that model is created with the correct identity'
+            assertModule(result)
+    }
+
+    def 'Parse and Validate a Yang Model Using a File'() {
+        given: 'a yang file that contains a yang model'
+            File file = new File(ClassLoader.getSystemClassLoader().getResource('bookstore.yang').getFile())
+        when: 'a model is parsed and validated'
+            def result = objectUnderTest.parseAndValidateModel(file)
+        then: 'Verify a schema context for that model is created with the correct identity'
+            assertModule(result)
+
+    }
+
+    def assertModule(SchemaContext schemaContext){
+        def optionalModule = schemaContext.findModule('bookstore', Revision.of('2020-09-15'))
+        return schemaContext.modules.size() == 1 && optionalModule.isPresent()
+    }
+
+    def 'Parse and Validate an Invalid Model'() {
+        given: 'a yang file that contains a invalid yang model'
+            File file = new File(ClassLoader.getSystemClassLoader().getResource('invalid.yang').getFile())
+        when: 'the model is parsed and validated'
+            objectUnderTest.parseAndValidateModel(file)
+        then: 'a CpsValidationException is thrown'
+            thrown(CpsValidationException)
+    }
+
+    def 'Store a SchemaContext'() {
+        expect: 'No exception to be thrown when a valid model (schema) is stored'
+            objectUnderTest.storeSchemaContext(Stub(SchemaContext.class), "sampleDataspace")
+    }
+
+    def 'Read a JSON object with a valid identifier'(){
+        given: 'that the data persistence service returns a JSON structure for identifier 1'
+            mockDataPersistencyService.getJsonById(1) >> '{name : hello}'
+        expect: 'that the same JSON structure is returned by CPS'
+            objectUnderTest.getJsonById(1) == '{name : hello}'
+    }
+
+    def 'Read a JSON object with an identifier that does not exist'(){
+        given: 'that the data persistence service throws an exception'
+            def exceptionThrownByPersistenceService = new IllegalStateException()
+            mockDataPersistencyService.getJsonById(_) >> {throw exceptionThrownByPersistenceService}
+        when: 'we try to get the JSON structure'
+            objectUnderTest.getJsonById(1);
+        then: 'the same exception is thrown by CPS'
+            thrown(IllegalStateException)
+    }
+
+    def 'Delete a JSON object with a valid identifier'(){
+        given: 'that the data persistence service can delete a JSON structure for identifier 1'
+            mockDataPersistencyService.deleteJsonById(1)
+        expect: 'No exception is thrown when we delete a JSON structure with identifier 1'
+            objectUnderTest.deleteJsonById(1)
+    }
+
+    def 'Delete a JSON object with an identifier that does not exist'(){
+        given: 'that the data persistence service throws an exception'
+            mockDataPersistencyService.deleteJsonById(_) >> {throw new IllegalStateException()}
+        when: 'we try to delete a JSON structure'
+            objectUnderTest.deleteJsonById(100);
+        then: 'the same exception is thrown by CPS'
+            thrown(IllegalStateException)
+    }
+}
\ No newline at end of file
diff --git a/cps-service/src/test/groovy/org/onap/cps/utils/YangUtilsSpec.groovy b/cps-service/src/test/groovy/org/onap/cps/utils/YangUtilsSpec.groovy
new file mode 100644
index 0000000000..8aabc48448
--- /dev/null
+++ b/cps-service/src/test/groovy/org/onap/cps/utils/YangUtilsSpec.groovy
@@ -0,0 +1,80 @@
+/*
+ * ============LICENSE_START=======================================================
+ *  Copyright (C) 2020 Nordix Foundation
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the "License");
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an "AS IS" BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+
+package org.onap.cps.utils
+
+import org.opendaylight.yangtools.yang.data.api.schema.NormalizedNode
+import org.opendaylight.yangtools.yang.common.QName
+import org.opendaylight.yangtools.yang.common.Revision
+import org.opendaylight.yangtools.yang.model.parser.api.YangSyntaxErrorException
+import spock.lang.Specification
+import spock.lang.Unroll
+
+class YangUtilsSpec extends Specification{
+    def 'Parsing a valid Yang Model'() {
+        given: 'a yang model (file)'
+            def file = new File(ClassLoader.getSystemClassLoader().getResource('bookstore.yang').getFile())
+        when: 'the file is parsed'
+            def result = YangUtils.parseYangModelFile(file)
+        then: 'the result contain 1 module of the correct name and revision'
+            result.modules.size() == 1
+            def optionalModule = result.findModule('bookstore', Revision.of('2020-09-15'))
+            optionalModule.isPresent()
+    }
+
+    @Unroll
+    def 'parsing invalid yang file (#description)'() {
+        given: 'a file with #description'
+            File file = new File(ClassLoader.getSystemClassLoader().getResource(filename).getFile());
+        when: 'the file is parsed'
+            YangUtils.parseYangModelFile(file)
+        then: 'an exception is thrown'
+            thrown(expectedException)
+        where: 'the following parameters are used'
+             filename           | description          || expectedException
+            'invalid.yang'      | 'no valid content'   || YangSyntaxErrorException
+            'someOtherFile.txt' | 'no .yang extension' || IllegalArgumentException
+    }
+
+    def 'Parsing a valid Json String'() {
+        given: 'a yang model (file)'
+            def jsonData = org.onap.cps.TestUtils.getResourceFileContent('bookstore.json')
+        and: 'a model for that data'
+            def file = new File(ClassLoader.getSystemClassLoader().getResource('bookstore.yang').getFile())
+            def schemaContext = YangUtils.parseYangModelFile(file)
+        when: 'the json data is parsed'
+            NormalizedNode<?, ?> result = YangUtils.parseJsonData(jsonData, schemaContext);
+        then: 'the result is a normalized node of the correct type'
+            result.nodeType == QName.create('org:onap:ccsdk:sample','2020-09-15','bookstore')
+    }
+
+    def 'Parsing an invalid Json String'() {
+        given: 'a yang model (file)'
+            def jsonData = '{incomplete json'
+        and: 'a model'
+            def file = new File(ClassLoader.getSystemClassLoader().getResource('bookstore.yang').getFile())
+            def schemaContext = YangUtils.parseYangModelFile(file)
+        when: 'the invalid json is parsed'
+            YangUtils.parseJsonData(jsonData, schemaContext);
+        then: ' an exception is thrown'
+            thrown(IllegalStateException)
+    }
+
+
+}