Introducing Spock/Groovy for Data Integration Tests

Replaced CpsAdminPersistenceServiceTest with CpsAdminPersistenceServiceSpec
Replaced CpsDataPersistenceServiceTest with CpsDataPersistenceServiceSpec
Replaced CpsModulePersistenceServiceTest with CpsModulePersistenceServiceSpec
Extracted out common integration test base
Rationalised test (there was a lot of duplication already!)

Issue-ID: CPS-160

Signed-off-by: ToineSiebelink <toine.siebelink@est.tech>
Change-Id: I3311533fba1398feb00b6adf4209399cea8d3a1b

4 files changed, 522 insertions, 0 deletions

diff --git a/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsAdminPersistenceServiceSpec.groovy b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsAdminPersistenceServiceSpec.groovy
new file mode 100644
index 000000000..fd3e96481
--- /dev/null
+++ b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsAdminPersistenceServiceSpec.groovy
@@ -0,0 +1,122 @@
+/*
+ * ============LICENSE_START=======================================================
+ *  Copyright (C) 2021 Nordix Foundation
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the "License");
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an "AS IS" BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+
+package org.onap.cps.spi.impl
+
+import org.onap.cps.spi.CpsAdminPersistenceService
+import org.onap.cps.spi.exceptions.AnchorAlreadyDefinedException
+import org.onap.cps.spi.exceptions.AnchorNotFoundException
+import org.onap.cps.spi.exceptions.DataspaceAlreadyDefinedException
+import org.onap.cps.spi.exceptions.DataspaceNotFoundException
+import org.onap.cps.spi.exceptions.SchemaSetNotFoundException
+import org.onap.cps.spi.model.Anchor
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.test.context.jdbc.Sql
+import spock.lang.Unroll
+
+class CpsAdminPersistenceServiceSpec extends CpsPersistenceSpecBase {
+
+    @Autowired
+    CpsAdminPersistenceService objectUnderTest
+
+    static final String SET_DATA = '/data/anchor.sql'
+    static final String EMPTY_DATASPACE_NAME = 'DATASPACE-002'
+
+    @Sql(CLEAR_DATA)
+    def 'Create and retrieve a new dataspace.'() {
+        when: 'a new dataspace is created'
+            def dataspaceName = 'some new dataspace'
+            objectUnderTest.createDataspace(dataspaceName)
+        then: 'that dataspace can be retrieved from the dataspace repository'
+            def dataspaceEntity = dataspaceRepository.findByName(dataspaceName).orElseThrow()
+            dataspaceEntity.id != null
+            dataspaceEntity.name == dataspaceName
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Attempt to create a duplicate dataspace.'() {
+        when: 'an attempt is made to create an already existing dataspace'
+            objectUnderTest.createDataspace(DATASPACE_NAME)
+        then: 'an exception that is is already defined is thrown with the correct details'
+            def thrown = thrown(DataspaceAlreadyDefinedException)
+            thrown.details.contains(DATASPACE_NAME)
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Create and retrieve a new anchor.'() {
+        when: 'a new anchor is created'
+            def newAnchorName = 'my new anchor'
+            objectUnderTest.createAnchor(DATASPACE_NAME, SCHEMA_SET_NAME1, newAnchorName)
+        then: 'that anchor can be retrieved'
+            def anchor = objectUnderTest.getAnchor(DATASPACE_NAME, newAnchorName)
+            anchor.name == newAnchorName
+            anchor.dataspaceName == DATASPACE_NAME
+            anchor.schemaSetName == SCHEMA_SET_NAME1
+    }
+
+    @Unroll
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Create anchor error scenario: #scenario.'() {
+        when: 'attempt to create new anchor named #anchorName in dataspace #dataspaceName with #schemaSetName'
+            objectUnderTest.createAnchor(dataspaceName, schemaSetName, anchorName)
+        then: 'an #expectedException is thrown'
+            thrown(expectedException)
+        where: 'the following data is used'
+            scenario                    | dataspaceName  | schemaSetName     | anchorName     || expectedException
+            'dataspace does not exist'  | 'unknown'      | 'not-relevant'    | 'not-relevant' || DataspaceNotFoundException
+            'schema set does not exist' | DATASPACE_NAME | 'unknown'         | 'not-relevant' || SchemaSetNotFoundException
+            'anchor already exists'     | DATASPACE_NAME |  SCHEMA_SET_NAME1 | ANCHOR_NAME1   || AnchorAlreadyDefinedException
+    }
+
+    @Unroll
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Get anchor error scenario: #scenario.'() {
+        when: 'attempt to get anchor named #anchorName in dataspace #dataspaceName'
+            objectUnderTest.getAnchor(dataspaceName, anchorName)
+        then: 'an #expectedException is thrown'
+            thrown(expectedException)
+        where: 'the following data is used'
+            scenario                    | dataspaceName  | anchorName     || expectedException
+            'dataspace does not exist'  | 'unknown'      | 'not-relevant' || DataspaceNotFoundException
+            'anchor does not exists'    | DATASPACE_NAME | 'unknown'      || AnchorNotFoundException
+    }
+
+    @Unroll
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Get all anchors in dataspace #dataspaceName.'() {
+        when: 'all anchors are retrieved from #DATASPACE_NAME'
+            def result = objectUnderTest.getAnchors(dataspaceName)
+        then: 'the expected collection of anchors is returned'
+            result.size() == expectedAnchors.size()
+            result.containsAll(expectedAnchors)
+        where: 'the following data is used'
+            dataspaceName        || expectedAnchors
+            DATASPACE_NAME       || [Anchor.builder().name(ANCHOR_NAME1).schemaSetName(SCHEMA_SET_NAME1).dataspaceName(DATASPACE_NAME).build(),
+                                     Anchor.builder().name(ANCHOR_NAME2).schemaSetName(SCHEMA_SET_NAME2).dataspaceName(DATASPACE_NAME).build()]
+            EMPTY_DATASPACE_NAME || []
+    }
+
+    @Sql(CLEAR_DATA)
+    def 'Get all anchors in unknown dataspace.'() {
+        when: 'attempt to get all anchors in an unknown dataspace'
+            objectUnderTest.getAnchors('unknown dataspace')
+        then: 'an DataspaceNotFoundException is thrown'
+            thrown(DataspaceNotFoundException)
+    }
+}
diff --git a/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsDataPersistenceServiceSpec.groovy b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsDataPersistenceServiceSpec.groovy
new file mode 100644
index 000000000..03e352a87
--- /dev/null
+++ b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsDataPersistenceServiceSpec.groovy
@@ -0,0 +1,150 @@
+/*
+ * ============LICENSE_START=======================================================
+ *  Copyright (C) 2021 Nordix Foundation
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the "License");
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an "AS IS" BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+package org.onap.cps.spi.impl
+
+import com.google.common.collect.ImmutableSet
+import org.onap.cps.spi.CpsDataPersistenceService
+import org.onap.cps.spi.exceptions.AnchorNotFoundException
+import org.onap.cps.spi.exceptions.DataNodeNotFoundException
+import org.onap.cps.spi.exceptions.DataspaceNotFoundException
+import org.onap.cps.spi.model.DataNode
+import org.onap.cps.spi.model.DataNodeBuilder
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.dao.DataIntegrityViolationException
+import org.springframework.test.context.jdbc.Sql
+
+class CpsDataPersistenceServiceSpec extends CpsPersistenceSpecBase {
+
+    @Autowired
+    CpsDataPersistenceService objectUnderTest
+
+    static final String SET_DATA = '/data/fragment.sql'
+    static final long ID_DATA_NODE_WITH_DESCENDANTS = 4001
+    static final String XPATH_DATA_NODE_WITH_DESCENDANTS = '/parent-1'
+
+    static final DataNode newDataNode = new DataNodeBuilder().build()
+    static DataNode existingDataNode
+    static DataNode existingChildDataNode
+
+    static {
+        existingDataNode = createDataNodeTree(XPATH_DATA_NODE_WITH_DESCENDANTS)
+        existingChildDataNode = createDataNodeTree('/parent-1/child-1')
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Get fragment with descendants.'() {
+        /*
+        TODO: This test is not really testing the object under test! Needs to be updated as part of CPS-71
+        Actually I think this test will become redundant once th store data node tests is asserted using
+        a new getByXpath() method in the service (object under test)
+        A lot of preloaded dat will become redundant then too
+         */
+        //
+        when: 'a fragment is retrieved from the repository'
+            def fragment = fragmentRepository.findById(ID_DATA_NODE_WITH_DESCENDANTS).orElseThrow()
+        then: 'it has the correct xpath'
+            fragment.xpath == '/parent-1'
+        and: 'it contains the children'
+            fragment.childFragments.size() == 1
+            def childFragment = fragment.childFragments[0]
+            childFragment.xpath == '/parent-1/child-1'
+        and: "and its children's children"
+            childFragment.childFragments.size() == 1
+            def grandchildFragment = childFragment.childFragments[0]
+            grandchildFragment.xpath == '/parent-1/child-1/grandchild-1'
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'StoreDataNode with descendants.'() {
+        when: 'a fragment with descendants is stored'
+            def parentXpath = "/parent-new"
+            def childXpath = "/parent-new/child-new"
+            def grandChildXpath = "/parent-new/child-new/grandchild-new"
+            objectUnderTest.storeDataNode(DATASPACE_NAME, ANCHOR_NAME1,
+                createDataNodeTree(parentXpath, childXpath, grandChildXpath))
+        then: 'it can be retrieved by its xpath'
+            def parentFragment = getFragmentByXpath(parentXpath)
+        and: 'it contains the children'
+            parentFragment.childFragments.size() == 1
+            def childFragment = parentFragment.childFragments[0]
+            childFragment.xpath == childXpath
+        and: "and its children's children"
+            childFragment.childFragments.size() == 1
+            def grandchildFragment = childFragment.childFragments[0]
+            grandchildFragment.xpath == grandChildXpath
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def  'Store datanode error scenario: #scenario.'() {
+        when: 'attempt to store a data node with #scenario'
+            objectUnderTest.storeDataNode(dataspaceName, anchorName, dataNode)
+        then: 'a #expectedException is thrown'
+            thrown(expectedException)
+        where: 'the following data is used'
+            scenario                    | dataspaceName  | anchorName     | dataNode         || expectedException
+            'dataspace does not exist'  | 'unknown'      | 'not-relevant' | newDataNode      || DataspaceNotFoundException
+            'schema set does not exist' | DATASPACE_NAME | 'unknown'      | newDataNode      || AnchorNotFoundException
+            'anchor already exists'     | DATASPACE_NAME | ANCHOR_NAME1   | existingDataNode || DataIntegrityViolationException
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Add a child to a Fragment that already has a child.'() {
+        given: ' a new child node'
+            def newChild = createDataNodeTree('xpath for new child')
+        when: 'the child is added to an existing parent with 1 child'
+            objectUnderTest.addChildDataNode(DATASPACE_NAME, ANCHOR_NAME1, XPATH_DATA_NODE_WITH_DESCENDANTS, newChild)
+        then: 'the parent is now has to 2 children'
+            def expectedExistingChildPath = '/parent-1/child-1'
+            def parentFragment = fragmentRepository.findById(ID_DATA_NODE_WITH_DESCENDANTS).orElseThrow()
+            parentFragment.getChildFragments().size() == 2
+        and : 'it still has the old child'
+            parentFragment.getChildFragments().find( {it.xpath == expectedExistingChildPath})
+        and : 'it has the new child'
+            parentFragment.getChildFragments().find( {it.xpath == newChild.xpath})
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def  'Add child error scenario: #scenario.'() {
+        when: 'attempt to add a child data node with #scenario'
+            objectUnderTest.addChildDataNode(DATASPACE_NAME, ANCHOR_NAME1, parentXpath, dataNode)
+        then: 'a #expectedException is thrown'
+            thrown(expectedException)
+        where: 'the following data is used'
+            scenario                 | parentXpath                      | dataNode              || expectedException
+            'parent does not exist'  | 'unknown'                        | newDataNode           || DataNodeNotFoundException
+            'already existing child' | XPATH_DATA_NODE_WITH_DESCENDANTS | existingChildDataNode || DataIntegrityViolationException
+    }
+
+    static def createDataNodeTree(String... xpaths) {
+        def dataNodeBuilder = new DataNodeBuilder().withXpath(xpaths[0])
+        if (xpaths.length > 1) {
+            def xPathsDescendant = Arrays.copyOfRange(xpaths, 1, xpaths.length)
+            def childDataNode = createDataNodeTree(xPathsDescendant)
+            dataNodeBuilder.withChildDataNodes(ImmutableSet.of(childDataNode))
+        }
+        dataNodeBuilder.build()
+    }
+
+    def getFragmentByXpath = xpath -> {
+        //TODO: Remove this method when CPS-71 gets implemented
+        fragmentRepository.findAll().stream()
+          .filter(fragment -> fragment.getXpath().contains(xpath)).findAny().orElseThrow()
+    }
+
+}
diff --git a/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsModulePersistenceServiceSpec.groovy b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsModulePersistenceServiceSpec.groovy
new file mode 100644
index 000000000..b0c13af3d
--- /dev/null
+++ b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsModulePersistenceServiceSpec.groovy
@@ -0,0 +1,194 @@
+/*
+ * ============LICENSE_START=======================================================
+ *  Copyright (C) 2021 Nordix Foundation
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the 'License');
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an 'AS IS' BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+package org.onap.cps.spi.impl
+
+import static org.onap.cps.spi.CascadeDeleteAllowed.CASCADE_DELETE_ALLOWED
+import static org.onap.cps.spi.CascadeDeleteAllowed.CASCADE_DELETE_PROHIBITED
+
+import org.onap.cps.spi.CpsAdminPersistenceService
+import org.onap.cps.spi.CpsModulePersistenceService
+import org.onap.cps.spi.entities.YangResourceEntity
+import org.onap.cps.spi.exceptions.DataspaceNotFoundException
+import org.onap.cps.spi.exceptions.SchemaSetAlreadyDefinedException
+import org.onap.cps.spi.exceptions.SchemaSetInUseException
+import org.onap.cps.spi.exceptions.SchemaSetNotFoundException
+import org.onap.cps.spi.repository.AnchorRepository
+import org.onap.cps.spi.repository.SchemaSetRepository
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.test.context.jdbc.Sql
+import spock.lang.Unroll
+
+class CpsModulePersistenceServiceSpec extends CpsPersistenceSpecBase {
+
+    @Autowired
+    CpsModulePersistenceService objectUnderTest
+
+    @Autowired
+    AnchorRepository anchorRepository
+
+    @Autowired
+    SchemaSetRepository schemaSetRepository
+
+    @Autowired
+    CpsAdminPersistenceService cpsAdminPersistenceService
+
+    static final String SET_DATA = '/data/schemaset.sql'
+    static final String EXISTING_SCHEMA_SET_NAME = SCHEMA_SET_NAME1
+    static final String SCHEMA_SET_NAME_NO_ANCHORS = 'SCHEMA-SET-100'
+    static final String SCHEMA_SET_NAME_WITH_ANCHORS_AND_DATA = 'SCHEMA-SET-101'
+    static final String SCHEMA_SET_NAME_NEW = 'SCHEMA-SET-NEW'
+
+    static final Long NEW_RESOURCE_ABSTRACT_ID = 0L
+    static final String NEW_RESOURCE_NAME = 'some new resource'
+    static final String NEW_RESOURCE_CONTENT = 'some resource content'
+    static final String NEW_RESOURCE_CHECKSUM = '8185b09f11e262f18043f0ea08803f46'
+
+    def newYangResourcesNameToContentMap = [(NEW_RESOURCE_NAME):NEW_RESOURCE_CONTENT]
+    def dataspaceEntity
+
+    def setup() {
+        dataspaceEntity = dataspaceRepository.getByName(DATASPACE_NAME)
+    }
+
+    @Unroll
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Store schema set error scenario: #scenario.'() {
+        when: 'attempt to store schema set #schemaSetName in dataspace #dataspaceName'
+            objectUnderTest.storeSchemaSet(dataspaceName, schemaSetName, newYangResourcesNameToContentMap)
+        then: 'an #expectedException is thrown'
+            thrown(expectedException)
+        where: 'the following data is used'
+            scenario                    | dataspaceName  | schemaSetName            || expectedException
+            'dataspace does not exist'  | 'unknown'      | 'not-relevant'           || DataspaceNotFoundException
+            'schema set already exists' | DATASPACE_NAME | EXISTING_SCHEMA_SET_NAME || SchemaSetAlreadyDefinedException
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Store new schema set.'() {
+        when: 'a new schemaset is stored'
+            objectUnderTest.storeSchemaSet(DATASPACE_NAME, SCHEMA_SET_NAME_NEW, newYangResourcesNameToContentMap)
+        then: 'the schema set is persisted correctly'
+            assertSchemaSetPersisted(DATASPACE_NAME, SCHEMA_SET_NAME_NEW, NEW_RESOURCE_ABSTRACT_ID, NEW_RESOURCE_NAME,
+                    NEW_RESOURCE_CONTENT, NEW_RESOURCE_CHECKSUM)
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Retrieving schema set (resources) by anchor.'() {
+        given: 'a new schema set is stored'
+            objectUnderTest.storeSchemaSet(DATASPACE_NAME, SCHEMA_SET_NAME_NEW, newYangResourcesNameToContentMap)
+        and: 'an anchor is created with that schema set'
+            cpsAdminPersistenceService.createAnchor(DATASPACE_NAME, SCHEMA_SET_NAME_NEW, ANCHOR_NAME1)
+        when: 'the schema set resources for that anchor is retrieved'
+            def result = objectUnderTest.getYangSchemaSetResources(DATASPACE_NAME, ANCHOR_NAME1)
+        then: 'the correct resources are returned'
+             result == newYangResourcesNameToContentMap
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Storing duplicate schema content.'() {
+        given: 'a new schema set with a resource with the same content as an existing resource'
+            def existingResourceContent = 'CONTENT-001'
+            def newYangResourcesNameToContentMap = [(NEW_RESOURCE_NAME):existingResourceContent]
+        when: 'the schema set with duplicate resource is stored'
+            objectUnderTest.storeSchemaSet(DATASPACE_NAME, SCHEMA_SET_NAME_NEW, newYangResourcesNameToContentMap)
+        then: 'the schema persisted (re)uses the existing id, name and has the same checksum'
+            def existingResourceId = 3001L
+            def existingResourceName = 'module1@2020-02-02.yang'
+            def existingResourceChecksum = '877e65a9f36d54e7702c3f073f6bc42b'
+            assertSchemaSetPersisted(DATASPACE_NAME, SCHEMA_SET_NAME_NEW,
+                    existingResourceId, existingResourceName, existingResourceContent, existingResourceChecksum)
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Delete schema set with cascade delete prohibited but no anchors using it'() {
+        when: 'a schema set is deleted with cascade-prohibited option'
+            objectUnderTest.deleteSchemaSet(DATASPACE_NAME, SCHEMA_SET_NAME_NO_ANCHORS,
+                    CASCADE_DELETE_PROHIBITED)
+        then: 'the schema set has been deleted'
+            schemaSetRepository.findByDataspaceAndName(dataspaceEntity, SCHEMA_SET_NAME_NO_ANCHORS).isPresent() == false
+        and: 'any orphaned (not used by any schema set anymore) yang resources are deleted'
+            def orphanedResourceId = 3100L
+            yangResourceRepository.findById(orphanedResourceId).isPresent() == false
+        and: 'any shared (still in use by other schema set) yang resources still persists'
+            def sharedResourceId = 3003L
+            yangResourceRepository.findById(sharedResourceId).isPresent()
+    }
+
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Delete schema set with cascade allowed.'() {
+        when: 'a schema set is deleted with cascade-allowed option'
+            objectUnderTest.deleteSchemaSet(DATASPACE_NAME, SCHEMA_SET_NAME_WITH_ANCHORS_AND_DATA,
+                    CASCADE_DELETE_ALLOWED)
+        then: 'the schema set has been deleted'
+            schemaSetRepository
+                    .findByDataspaceAndName(dataspaceEntity, SCHEMA_SET_NAME_WITH_ANCHORS_AND_DATA).isPresent() == false
+        and: 'the associated anchors are removed'
+            def associatedAnchorsIds = [ 6001, 6002 ]
+            associatedAnchorsIds.each {anchorRepository.findById(it).isPresent() == false }
+        and: 'the fragment(s) under those anchors are removed'
+            def fragmentUnderAnchor1Id = 7001L
+            fragmentRepository.findById(fragmentUnderAnchor1Id).isPresent() == false
+        and: 'the shared resources still persist'
+            def sharedResourceIds = [ 3003L, 3004L ]
+            sharedResourceIds.each {yangResourceRepository.findById(it).isPresent() }
+    }
+
+    @Unroll
+    @Sql([CLEAR_DATA, SET_DATA])
+    def 'Delete schema set error scenario: #scenario.'() {
+        when: 'attempt to delete a schema set where #scenario'
+            objectUnderTest.deleteSchemaSet(dataspaceName, schemaSetName, CASCADE_DELETE_PROHIBITED)
+        then: 'an #expectedException is thrown'
+            thrown(expectedException)
+        where: 'the following data is used'
+            scenario                                   | dataspaceName  | schemaSetName                         || expectedException
+            'dataspace does not exist'                 | 'unknown'      | 'not-relevant'                        || DataspaceNotFoundException
+            'schema set does not exists'               | DATASPACE_NAME | 'unknown'                             || SchemaSetNotFoundException
+            'cascade prohibited but schema set in use' | DATASPACE_NAME | SCHEMA_SET_NAME_WITH_ANCHORS_AND_DATA || SchemaSetInUseException
+    }
+
+    def assertSchemaSetPersisted(expectedDataspaceName,
+                             expectedSchemaSetName,
+                             expectedYangResourceId,
+                             expectedYangResourceName,
+                             expectedYangResourceContent,
+                             expectedYangResourceChecksum) {
+        // assert the schema set is persisted
+        def schemaSetEntity = schemaSetRepository
+                .findByDataspaceAndName(dataspaceEntity, expectedSchemaSetName).orElseThrow()
+        assert schemaSetEntity.name == expectedSchemaSetName
+        assert schemaSetEntity.dataspace.name == expectedDataspaceName
+
+        // assert the attached yang resource is persisted
+        def yangResourceEntities = schemaSetEntity.getYangResources()
+        yangResourceEntities.size() == 1
+
+        // assert the attached yang resource content
+        YangResourceEntity yangResourceEntity = yangResourceEntities.iterator().next()
+        assert yangResourceEntity.id != null
+        if (expectedYangResourceId != NEW_RESOURCE_ABSTRACT_ID) {
+            // existing resource with known id
+            assert yangResourceEntity.id == expectedYangResourceId
+        }
+        yangResourceEntity.name == expectedYangResourceName
+        yangResourceEntity.content == expectedYangResourceContent
+        yangResourceEntity.checksum == expectedYangResourceChecksum
+    }
+
+}
diff --git a/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsPersistenceSpecBase.groovy b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsPersistenceSpecBase.groovy
new file mode 100644
index 000000000..54807efd2
--- /dev/null
+++ b/cps-ri/src/test/groovy/org/onap/cps/spi/impl/CpsPersistenceSpecBase.groovy
@@ -0,0 +1,56 @@
+/*
+ * ============LICENSE_START=======================================================
+ *  Copyright (C) 2021 Nordix Foundation
+ *  ================================================================================
+ *  Licensed under the Apache License, Version 2.0 (the 'License');
+ *  you may not use this file except in compliance with the License.
+ *  You may obtain a copy of the License at
+ *
+ *        http://www.apache.org/licenses/LICENSE-2.0
+ *  Unless required by applicable law or agreed to in writing, software
+ *  distributed under the License is distributed on an 'AS IS' BASIS,
+ *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ *  See the License for the specific language governing permissions and
+ *  limitations under the License.
+ *
+ *  SPDX-License-Identifier: Apache-2.0
+ *  ============LICENSE_END=========================================================
+ */
+
+package org.onap.cps.spi.impl
+
+import org.onap.cps.DatabaseTestContainer
+import org.onap.cps.spi.repository.DataspaceRepository
+import org.onap.cps.spi.repository.FragmentRepository
+import org.onap.cps.spi.repository.YangResourceRepository
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.boot.test.context.SpringBootTest
+import org.testcontainers.spock.Testcontainers
+import spock.lang.Shared
+import spock.lang.Specification
+
+@SpringBootTest
+@Testcontainers
+class CpsPersistenceSpecBase extends Specification {
+
+    @Shared
+    DatabaseTestContainer databaseTestContainer = DatabaseTestContainer.getInstance()
+
+    @Autowired
+    DataspaceRepository dataspaceRepository
+
+    @Autowired
+    YangResourceRepository yangResourceRepository
+
+    @Autowired
+    FragmentRepository fragmentRepository
+
+    static final String CLEAR_DATA = '/data/clear-all.sql'
+
+    static final String DATASPACE_NAME = 'DATASPACE-001'
+    static final String SCHEMA_SET_NAME1 = 'SCHEMA-SET-001'
+    static final String SCHEMA_SET_NAME2 = 'SCHEMA-SET-002'
+    static final String ANCHOR_NAME1 = 'ANCHOR-001'
+    static final String ANCHOR_NAME2 = 'ANCHOR-002'
+
+}